* The first step is to code victim age into categories; if your variable is not a numeric one, convert it first

RECODE
  v_age
  (0=8)  (.1 thru 5=1)  (6 thru 11=2)  (12 thru 17=3)  (18 thru 24=4)  (25
  thru 44=5)  (45 thru 64=6)  (65 thru 99=7)  INTO  vage_cat .
VARIABLE LABELS vage_cat 'Victim Age Category'.
value labels vage_cat
1 '0 - 5'
2 '6 - 11'
3 '12 - 17'
4 '18 - 24'
5 '25 - 44'
6 '45 - 64'
7 '65 and over'
8 'Unknown'.
EXECUTE .

* Now we create the relationship categories 

DO REPEAT ovr = ovr1 to ovr10/
   ovrcat = ovrcat1 to ovrcat10.
RECODE
  ovr ('SE','CS','PA','SB','CH','GP','GC','IL','SP','SC','SS','OF' = 1)
      ('AQ','FR','NE','BE','CF','EE','ER','OK','BG','XS','HR','RU','ST','VO' = 2)
      ('  ' = SYSMIS)INTO ovrcat.
END REPEAT.
value labels ovrcat1 to ovrcat10
1 'Family Member'
2 'Other'.
execute.

RECODE
  ovrcat1
  (1=1) (2=3)  INTO  fam_oth .
EXECUTE .
DO IF (ovrcat2 = 1 | ovrcat3 = 1 | ovrcat4 = 1 | ovrcat5 = 1 | ovrcat6 = 1 |
  ovrcat7 = 1 | ovrcat8 = 1 | ovrcat9 = 1 | ovrcat10 = 1) .
RECODE
  ovrcat1
  (2=2)  INTO  fam_oth .
END IF .
execute.
DO IF (ovrcat2 = 2 | ovrcat3 = 2 | ovrcat4 = 2 | ovrcat5 = 2 | ovrcat6 = 2 |
  ovrcat7 = 2 | ovrcat8 = 2 | ovrcat9 = 2 | ovrcat10 = 2) .
RECODE
  ovrcat1
  (1=2)  INTO  fam_oth .
END IF .
value labels fam_oth
1 'Family Member'
2 'Family Member and Other'
3 'Other'.
execute.

* The last step is to create the table

CROSSTABS
  /TABLES=vage_cat  BY fam_oth
  /FORMAT= AVALUE TABLES
  /CELLS= ROW .