* Location of Juvenile and Adult Property Crime Victimizations.

GET FILE='Directory\Path\US99 victim segment.sav'.
RECODE v_age (10 thru 17 = 1)(18 thru 99 = 2)(else = 0)INTO agegrp.
MISSING VALUES agegrp(0).
VALUE LABELS agegrp
 1 'Juveniles' 2 'Adults'.

RECODE msvoff (90,110,120,130 = 1)
   (140,160,167,150 = 2)
   (else = 0)INTO msvoffgp.
VALUE LABELS msvoffgp
  1 'Violent Crimes'
  2 'Property Crimes'
  0 'Missing/Not applicable'.

SELECT IF (msvoffgp gt 0 and agegrp gt 0).
SORT CASES BY ori inc_num.


SAVE OUTFILE = 'Directory\Path\location victim segment.sav'/KEEP = 
  ori inc_num msvoff v_age agegrp msvoffgp. 
GET FILE = 'Directory\Path\location victim segment.sav'.


MATCH FILES /FILE=*
 /TABLE='Directory\Path\1999 Incident.sav'
 /DROP = inc_yr inc_mo inc_dy inc_hr rptdate aggasl arfemale arr0509 arr1017 
  arr1524 arr65 arr_cnt arradult arrmale asl_arr att_comp bur bur_arr clr_arr 
  clr_excp firearm indivl lar lar_arr msioff mur mur_arr mvt mvt_arr 
  oasl_arr off1017 off1524 off65 off_cnt offadult offemale offmale ofns_cnt 
  oth_asl rap rap_arr rob rob_arr vadult vage1017 vage1524 vage65 vfemale 
  vic_cnt vic_inj vlt18 vmale
 /BY ori inc_num.


RECODE inc_loc 
  (20 = 1)
  (2,3,5,7,8,9,12,17,21,23,24 = 2)
  (18 = 3)
  (22 = 4)
  (1,10,13,16 = 5)
  (else = 6)into location.
VARIABLE LABELS location 'Type of location'.
VALUE LABELS location
  1 'Residence'
  2 'Commercial place'
  3 'Parking facility'
  4 'School'
  5 'Open area, street, public transportation'
  6 'Other place'.

TEMPORARY.
  VARIABLE LABELS msvoffgp '' agegrp '' .
TABLES
  /FORMAT BLANK MISSING('.')
  /GBASE=CASES
  /FTOTAL= $t000001 "Total"
  /TABLE=location + $t000001  BY msvoffgp > agegrp
  /STATISTICS
  cpct( agegrp( PCT5.0 ) '':msvoffgp agegrp )
  /TITLE  'Location of Juvenile and Adult Crime Victimizations'.