* Frequency Distribution for Victim-Offender Relationship by Offender 
  Victim Age Group and Location for Robbery.


GET FILE='Directory\Path\US99 victim segment.sav'.

COMPUTE robbery = 0.
DO REPEAT voff = voff1 to voff10.
IF (voff = 120 and v_type = 'I')robbery = 1.
END REPEAT.
SELECT IF (robbery = 1).
SAVE OUTFILE = 'Directory\Path\Robbery Victims.sav'.

GET FILE = 'Directory\Path\Robbery Victims.sav'.
SORT CASES BY ori inc_num vic_num.
DO IF (ofnseq1 gt 0).
XSAVE OUTFILE = 'Directory\Path\ofnseq1.sav'
  /DROP = ofnseq2 to ofnseq10 ovr2 to ovr10
  /RENAME = (ofnseq1 ovr1 =ofnseq ovr).
END IF.
DO IF (ofnseq2 gt 0).
XSAVE OUTFILE = 'Directory\Path\ofnseq2.sav'
  /DROP = ofnseq1 ofnseq3 to ofnseq10 ovr1 ovr3 to ovr10
  /RENAME = (ofnseq2 ovr2 =ofnseq ovr).
END IF.
DO IF (ofnseq3 gt 0).
XSAVE OUTFILE = 'Directory\Path\ofnseq3.sav'
  /DROP = ofnseq1 ofnseq2 ofnseq4 to ofnseq10
          ovr1 ovr2 ovr4 to ovr10
  /RENAME = (ofnseq3 ovr3 =ofnseq ovr).
END IF.
DO IF (ofnseq4 gt 0).
XSAVE OUTFILE = 'Directory\Path\ofnseq4.sav'
  /DROP = ofnseq1 to ofnseq3 ofnseq5 to ofnseq10
          ovr1 to ovr3 ovr5 to ovr10
  /RENAME = (ofnseq4 ovr4 =ofnseq ovr).
END IF.
DO IF (ofnseq5 gt 0).
XSAVE OUTFILE = 'Directory\Path\ofnseq5.sav'
  /DROP = ofnseq1 to ofnseq4 ofnseq6 to ofnseq10
          ovr1 to ovr4  ovr6 to ovr10
  /RENAME = (ofnseq5 ovr5 =ofnseq ovr).
END IF.
DO IF (ofnseq6 gt 0).
XSAVE OUTFILE = 'Directory\Path\ofnseq6.sav'
  /DROP = ofnseq1 to ofnseq5 ofnseq7 to ofnseq10
          ovr1 to ovr5 ovr7 to ovr10
  /RENAME = (ofnseq6 ovr6 =ofnseq ovr).
END IF.
DO IF (ofnseq7 gt 0).
XSAVE OUTFILE = 'Directory\Path\ofnseq7.sav'
  /DROP = ofnseq1 to ofnseq6 ofnseq8 to ofnseq10
          ovr1 to ovr6 ovr8 to ovr10
  /RENAME = (ofnseq7 ovr7 =ofnseq ovr).
END IF.
DO IF (ofnseq8 gt 0).
XSAVE OUTFILE = 'Directory\Path\ofnseq8.sav'
  /DROP = ofnseq1 to ofnseq7 ofnseq9 to ofnseq10
          ovr1 to ovr7 ovr9 to ovr10
  /RENAME = (ofnseq8 ovr8 = ofnseq ovr).
END IF.
DO IF (ofnseq9 gt 0).
XSAVE OUTFILE = 'Directory\Path\ofnseq9.sav'
  /DROP = ofnseq10 ofnseq1 to ofnseq8 ovr10 ovr1 to ovr8
  /RENAME = (ofnseq9 ovr9 =ofnseq ovr).
END IF.
DO IF (ofnseq10 gt 0).
XSAVE OUTFILE = 'Directory\Path\ofnseq10.sav'
  /DROP = ofnseq1 to ofnseq9 ovr1 to ovr9
  /RENAME = (ofnseq10 ovr10 =ofnseq ovr).
END IF.
EXECUTE.


ADD FILES /FILE= 'Directory\Path\ofnseq1.sav'
 /FILE= 'Directory\Path\ofnseq2.sav'
 /FILE= 'Directory\Path\ofnseq3.sav'
 /FILE= 'Directory\Path\ofnseq4.sav'
 /FILE= 'Directory\Path\ofnseq5.sav'
 /FILE= 'Directory\Path\ofnseq6.sav'
 /FILE= 'Directory\Path\ofnseq7.sav'
 /FILE= 'Directory\Path\ofnseq8.sav'
 /FILE= 'Directory\Path\ofnseq9.sav'
 /FILE= 'Directory\Path\ofnseq10.sav'.
SORT cases by ori inc_num ofnseq vic_num.
SAVE OUTFILE = 'Directory\Path\vofnseq.sav'.


MATCH FILES /FILE=*
 /TABLE = 'Directory\Path\US99 offender segment.sav'
 /BY ori inc_num ofnseq
 /DROP= inc_date v_ethnic v_inj1 v_inj2 v_inj3 v_inj4 v_inj5 v_race v_resid
  vcircum1 vcircum2 vic_age vic_sex vjusthom voff1 voff10 voff2 voff3 voff4
  voff5 voff6 voff7 voff8 voff9.
SAVE OUTFILE = 'Directory\Path\vofnseq.sav'.

MATCH FILES /FILE=*
 /TABLE='Directory\Path\1999 Incident.sav'
 /BY ori inc_num
 /DROP= aggasl arfemale arr0509 arr1017 arr1524 arr65 arr_cnt arradult
  arrmale asl_arr att_comp bur bur_arr clr_arr clr_excp firearm inc_dy inc_mo
  inc_yr indivl lar lar_arr msioff mur mur_arr mvt mvt_arr oasl_arr
  off1017 off1524 off65 off_cnt offadult offemale offmale ofns_cnt oth_asl rap
  rap_arr rob rob_arr vadult vage1017 vage1524 vage65 vfemale vic_cnt vic_inj
  vlt18 vmale.
SAVE OUTFILE = 'Directory\Path\Robbery victim-offender incident.sav'.


RECODE
  OVR ('SE','CS','PA','SB','CH','GP',
       'GC','IL','SP','SC','SS','OF','XS','VO' 
       'AQ','FR','NE','BE','BG','CF','HR','XS','EE','ER','OK' = 1)
      ('ST' = 2) ('RU','  ' = -1)INTO OVR_RCD.
MISSING VALUES ovr_rcd (-1).
VALUE LABELS ovr_rcd
    1 'Known to Victim'
    2 'Stranger'
    -1 'Missing Relationship Information'.
VARIABLE LABELS ovr_rcd 'VICTIM TO OFFENDER RELATIONSHIP RECODED'.
FREQ ovr_rcd.
RECODE inc_loc (20 = 1)(else = 0)into Location.
VALUE LABELS location 1 'Offense occurred at a home or residence'
   0 'Other location'.
RECODE v_age (.1 thru 64 = 1)(65 thru 98 = 2)into vagegrp.
VALUE LABELS vagegrp 1 'Under 65' 2 'Age 65 or older'.
RECODE off_age (10 thru 24 = 1)(25 thru 98 = 2)into oagegrp.
VALUE LABELS oagegrp 1 'Age 24 or younger' 2 'Age 25 or older'.

SAVE OUTFILE = 'Directory\Path\Robbery victim-offender incident.sav'.

SET TLook 'C:\Program Files\SPSS\Looks\Academic 2.tlo' TFit Labels.
TEMPORARY.
  VARIABLE LABELS oagegrp '' ovr_rcd '' vagegrp '' location '' .
TABLES
  /FORMAT BLANK MISSING('.')
  /GBASE=CASES
  /TABLE=oagegrp > ovr_rcd   BY vagegrp > location
  /STATISTICS
  count( location( F5.0 ) 'Number')
  cpct( location( PCT5.1 ) '(%)':vagegrp location )
 /TITLE  'Frequency Distribution for Victim-Offender Relationship by' +
 'Offender Age Group Victim Age Group and Location for Robbery'.