*Victim Injury by the Three Traditional Age Groups for Elders.


GET FILE='Directory\Path\NIBRS victim segment.sav'.
COMPUTE rob = 0.
DO REPEAT voff = voff1 TO voff10.
IF (voff = 120)rob = 1.
END REPEAT.
 
SELECT IF (rob = 1).
SAVE OUTFILE='Directory\Path\victim robbery.sav'/keep = 
  ori inc_num v_age v_inj1 to v_inj5 vic_sex msvoff.
GET FILE = 'Directory\Path\victim robbery.sav'.

RECODE v_age (.1 thru 64 = 0)
  (65 thru 74 = 1)(75 thru 84 = 2)(85 thru 99 = 3)
   INTO agegrp65.
VALUE LABELS agegrp65 0 'Age 64 and younger'
   1 '65 thru 74' 2 '75 thru 84' 3 '85 and older'.
MISSING VALUES agegrp65 (0).

DO REPEAT v_inj = v_inj1 to v_inj5/
   rcd = inj1 to inj5.
RECODE v_inj ('B','I','L','O','T','U' = 2)
  ('M' = 3)('N' = 4)(' ' = -1) INTO rcd.
END REPEAT.
VALUE LABELS inj1 to inj5 1 'Death'
  2 'Physical injury'
  3 'Apparent minor injury'
  4 'No injury'
  -1 'Missing' 9 'Not applicable'.
MISSING VALUES inj1 to inj5 (-1).
COMPUTE msvinj = min.1(inj1 to inj5).
IF (msvoff = 90)msvinj = 1.
VALUE LABELS msvinj 1 'Death'
  2 'Serious physical injury'
  3 'Apparent minor injury'
  4 'No injury'
  -1 'Missing'.
VALUE LABELS vic_sex 'M' 'Male' 'F' 'Female'.
USE ALL.
COMPUTE filter_$=(vic_sex ~= 'U').
VARIABLE LABEL filter_$ "vic_sex ~= 'U' (FILTER)".
VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.

SET TLook 'Directory\Path\apa.tlo' TFit Labels.

TEMPORARY.
  VARIABLE LABELS msvinj '' agegrp65 '' vic_sex '' .
TABLES
  /FORMAT BLANK MISSING('.')
  /GBASE=CASES
  /TABLE= msvinj by agegrp65 > vic_sex   
  /STATISTICS
  count( vic_sex( F5.0 ) 'Number')
  cpct( vic_sex( PCT5.1 ) '(%)':agegrp65 vic_sex ) 
  /TITLE  'Victim Injury by the Three Traditional Age Groups for Elders'.