*VICTIM INJURY, OFFENDER NUMBER TO BE RELATED, AND VICTIM-OFFENDER RELATIONSHIP*.
********************************************************************************
*For those offenses for which a victim injury, an offender number
*to be related, or a victim-offender relationship is required, is one
*reported on the victim segment? 
***********************************************************.
*For nine person offenses -- kidnaping/abduction, forcible rape,
*forcible sodomy, sexual assault with an object, forcible fondling,
*robbery, aggravated assault, simple assault, extortion/blackmail
*the FBI coding rules require the reporting of the type of victim
*injury on the victim data segment.  For all crimes against persons
*and robberies, the offender number to be related and the victim-offender
*relationship variables on the victim data segment are required.  In
*addition to the nine offenses listed above, the following offenses are
*included in the latter requirement: murder and nonnegligent manslaughter,
*negligent homicide, justifiable homicide, intimidation, incest,and
*statutory rape.  The coding rules for these data fields are listed
*in the FBI's Data Collection Guidelines and are incorporated into this
*quality control example for the victim data segment. To illustrate how
*an agency can self-test, one month's data from one of the NIBRS certified
*localities reporting to the FBI in 1999 was modified.  This example relies
*upon single agency data sets.
***********************************************************.
*Preparing the Victim Segment File
***********************************************************
*Selecting the Records for Analysis
***********************************************************.
*To examine victim injury coding, the first step is to retrieve the
*victim data segment file and create a new variable called INJCHECK,
*initially set at zero. According to FBI coding guidelines, a value for
*victim injury is required for persons who report one or more of nine
*specific offenses: kidnaping/abduction, forcible rape, forcible sodomy,
*sexual assault with an object, forcible fondling, robbery, aggravated
*assault, simple assault, extortion/blackmail. For each victim offense
*variable (V_OFF 1 through 10), if the victim type (V_TYPE) is “I” for
*individual and the victim offense (V_OFF) is one of the nine that require
*the reporting of victim injury, then the new variable INJCHECK is assigned
*a value of 1. 
***********************************************************.
GET FILE= = 'Directory:/Path/Victim Segment.sav'.          
COMPUTE injcheck = 0.
DO REPEAT voff = v_off1 to v_off10.
IF (v_type = 'I' and 
   (voff = '100' or
    voff = '11A' or
    voff = '11B' or
    voff = '11C' or
    voff = '11D' or
    voff = '120' or
    voff = '13A' or
    voff = '13B' or
    voff = '210'))injcheck = 1.
END REPEAT.
***********************************************************
*To check for the presence of victim-offender relationship codes and
*offender number to be related reporting, the first step is to create a
*new variable (OVRCHECK) to identify the records for which these variables
*are required. OVRCHECK is initially set at zero.  Then, for each victim
*offense variable (V_OFF 1 through 10), if the victim type (V_TYPE) is “I”
*for individual and the victim offense (V_OFF) is one which requires a
*victim-offender relationship, then the new variable OVRCHECK is assigned
*a value of 1.  The FBI coding rules require a victim-offender relationship
*(OVR) be assigned to each offender number to be related in the victim
*data segment.
***********************************************************.
COMPUTE ovrcheck = 0.
DO REPEAT voff = v_off1 to v_off10.
IF (v_type = 'I' and
   (voff = '09A' or
    voff = '09B' or 
    voff = '09C' or
    voff = '100' or
    voff = '11A' or
    voff = '11B' or
    voff = '11C' or
    voff = '120' or
    voff = '13A' or
    voff = '13B' or
    voff = '13C' or
    voff = '36A' or
    voff = '36B'))ovrcheck = 1.
END REPEAT.
***********************************************************
*Assign Data Labels
***********************************************************.
VALUE LABELS
  v_inj1 to v_inj5
     'N' 'None'
     'B' 'Apparent Broken Bones'
     'I' 'Possible Internal Injury'
     'L' 'Severe Laceration'
     'M' 'Apparent Minor Injury'
     'O' 'Other Major Injury'
     'T' 'Loss of Teeth'
     'U' 'Unconsciousness'/
ovr1 to ovr10
'SE' 'Victim was Spouse'
'CS' 'Victim was Common-law Spouse'
'PA' 'Victim was Parent'
'SB' 'Victim was Sibling'
'CH' 'Victim was Child'
'GP' 'Victim was Grandparent'
'GC' 'Victim was Grandchild'
'IL' 'Victim was In-law'
'SP' 'Victim was Stepparent'
'SC' 'Victim was Stepchild'
'SS' 'Victim was Stepsibling'
'OF' 'Victim was Other Family Member'
'VO' 'Victim was Offender'
'AQ' 'Victim was Acquaintance'
'FR' 'Victim was Friend'
'NE' 'Victim was Neighbor'
'BE' 'Victim was Babysitter'
'BG' 'Victim was Boyfriend/Girlfriend'
'CF' 'Victim was Child of Boyfriend/Girlfriend'
'HR' 'Victim was Homosexual Relationship'
'XS' 'Victim was Ex-Spouse'
'EE' 'Victim was Employee'
'ER' 'Victim was Employer'
'OK' 'Victim was Otherwise Known'
'RU' 'Relationship Unknown'
'ST' 'Victim was Stranger'.
***********************************************************
*Generating the Lists and Tables
***********************************************************.
*A CROSSTABS will show the joint distribution victim injury by injury check.
*The existing variable V_INJ1 is the first of the up to five victim injury
*variables.  The new variable INJCHECK acts as a flag indicating that at
*least one of the target offenses was coded for a victim.  If one of the
*target offenses was coded, then a victim injury should also be coded. 
***********************************************************.
CROSSTABS
  /TABLES= v_inj1 BY injcheck
  /FORMAT= AVALUE TABLES
  /CELLS= COUNT .
************************************************************
*Similar in concept to the new variable INJCHECK, OVERCHECK acts as a
*flag for records that should include values for victim-offender
*relationship and offender number to be related.
*The CROSSTABS command below will generate two joint distribution tables.
*The first will show the first victim-offender relationship variable (OVR1)
*by the variable OVRCHECK. This table allows one to determine whether victim
*segment records that are supposed to have victim-offender relationship data
*(1) contain data, and (2) contain valid relationship codes. The second table
*will show the first offender number to be related variable (OFNSEQ1) by the
*variable OVRCHECK, which allows one to verify that each victim record that
*requires an offender number to be related actually contains a valid value in
*the first occurrence of that variable (OFNSEQ1).
***********************************************************.
CROSSTABS
  /TABLES=ovr1 ofnseq1 BY ovrcheck
  /MISSING = INCLUDE
  /FORMAT= AVALUE TABLES
  /CELLS= COUNT .
***********************************************************
*To identify any records that are missing either the victim-offender
*relationship code (OVR1) or the offender number to be related (OFNSEQ1),
*a SELECT IF is run. The LIST will show the originating agency identifier (ORI),
*incident number (INC_NUM), and the offense code (V_OFF1) for any records for
*which the victim-offender relationship or offender number to be related are
*missing.
***********************************************************.
TEMPORARY.
SELECT IF (ovrcheck = 1 and (ovr1 = '  ' or sysmis(ofnseq1))).
LIST ori inc_num v_type v_off1 ofnseq1 ovr1.
***********************************************************
*As an alternative, the list above could show also the second offender
*number to be related (OFNSEQ2) and victim-offender relationship (OVR2).
*This would allow a check to see whether records that required but were
*missing a value in OFNSEQ1 and OVR1 might be coded with the correct values
*in the placeholders for the second occurrences of these variables rather
*than the first.
***********************************************************.