*HOMICIDE OFFENSES: QUALITY CONTROL OF VICTIM SEGMENT REQUIRED VARIABLES*.
*************************************************************************************
*For incidents that involve the homicide offenses of murder and nonnegligent
*manslaughter, negligent homicide, or justifiable homicide, are the required
*victim segment data fields completed and are the values valid?
*************************************************************************************.
*For the homicide offenses, the FBI requires the following victim segment
*data fields: type of victim, offender number to be related, relationship of
*victim to offender, aggravated assault/homicide circumstances, and additional
*justifiable homicide circumstance (for justifiable homicide offenses only).
*The allowable values for these data fields are listed in the FBI's Data
*Collection Guidelines and are incorporated into this example.  This data check
*can be performed on data sets at the local or state level.  The results will
*show which victim segment records need to be researched and corrected before
*submission at the state or national level.  The narrative below explains the
*SPSS code used to prepare the file and to produce the lists and tables needed
*for quality control purposes.  The following example uses a single agency data set.
*To illustrate how an agency can self-audit, one month's data from one of the NIBRS
*certified localities reporting to the FBI in 1999 was modified.
*************************************************************************************.
*Defining Homicides and Defining Value Labels for Required Variables
*************************************************************************************
*The block of code directly below retrieves and reviews the victim segment records
*to identify those with a homicide offense.  For the victim segment records, the
*first step is to create a new variable called HOMICIDE so that only records for
*which a homicide was recorded will be examined. Each victim offense variable
*(V_OFF 1 through 10) is evaluated for homicide offenses.  If no homicide offense
*was recorded, then the new variable HOMICIDE is assigned a value of 0.  A value 1
*is assigned for murder or nonnegligent homicide, 2 for negligent manslaughter, or 3
*for justifiable homicide.  Value labels are assigned for the new variable HOMICIDE.
*Next, the valid value labels for aggravated assault/homicide circumstances
*and additional justifiable homicide circumstance are assigned. A code representing
*the circumstances surrounding the offense is required for all homicide offenses.
*For murder and nonnegligent homicide, there are ten valid values (01 – 10, below)
*to describe the circumstances of the offense, and up to two valid values can be
*recorded.  For negligent manslaughter, there are five valid values (30 – 34, below)
*and for justifiable homicide (20 – 21, below) there are two valid values.  For
*these two homicide offenses, only one valid value can be recorded to describe the
*circumstances.  Justifiable homicide offenses also require further specification
*(A – G, below), and only one value is allowed.  In this next step, value labels are
*assigned to the following variables: victim aggravated assault/homicide circumstance
*(VCIRCUM1 and VCIRCUM2), and victim additional justifiable homicide circumstances
*(VJUSTHOM).
*Next, the value labels for the variable type of victim (V_TYPE)
*are assigned.  The victim type in homicide offenses must be "individual".
*Finally, the victim segment record must show the nature of the relationship
*between the victim and the offender.  There should be a sequential number
*(OFNSEQ) assigned to each offender and the relationship of the victim-offender
*relationship (OVR) must be defined for each.  Up to ten offenders can be
*assigned a sequence number and defined by relationship to the victim.  The
*valid values for victim-offender relationship are assigned next.
*************************************************************************************.
GET FILE= 'Directory:\Path\Victim Segment.sav'.
COMPUTE Homicide = 0.
DO REPEAT voff = v_off1 to v_off10.
IF (voff = '09A') homicide = 1.
IF (voff = '09B') homicide = 2.
IF (voff = '09C') homicide = 3.
END REPEAT.
VALUE LABELS homicide 0 'Not a homicide'
   1 'Murder' 2 'Manslaughter' 
   3 'Justifiable homicide'/
 vcircum1 vcircum2 
  '01' 'Argument'
  '02' 'Assault/Homicide on Law Enforcement Officer'
  '03' 'Drug dealing'
  '04' 'Gangland'
  '05' 'Juvenile gang'
  '06' "Lover's quarrel"
  '07' 'Mercy killing'
  '08' 'Other felony involved'
  '09' 'Other circumstances'
  '10' 'Unknown circumstances'
  '20' 'Criminal killed by private citizen'
  '21' 'Criminal killed by police officer'
  '30' 'Child playing with weapon'
  '31' 'Gun-cleaning accident'
  '32' 'Hunting accident'
  '33' 'Other negligent weapon handling'
  '34' 'Other negligent killing' /
 vjusthom
  'A' 'Criminal attacked officer, officer killed criminal'
  'B' 'Criminal attacked officer, criminal killed by other officer'
  'C' 'Criminal attacked a civilian'
  'D' 'Criminal attempted flight from a crime'
  'E' 'Criminal killed in commission of a crime'
  'F' 'Criminal resisted arrest'
  'G' 'Unable to determine/not enough information'/
 v_type 'I' 'Individual'
   'B' 'Business' 'F' 'Financial Institution'
   'G' 'Government' 'R' 'Religious Organization'
   'S' 'Society/Public' 'O' 'Other' 'U' 'Unknown'/
 ovr1 to ovr10
  'SE' 'Victim was Spouse'
  'CS' 'Victim was common-law Spouse'
  'PA' 'Victim was Parent'
  'SB' 'Victim was Sibling'
  'CH' 'Victim was Child'
  'GP' 'Victim was Grandparent'
  'GC' 'Victim was Grandchild'
  'IL' 'Victim was in-law'
  'SP' 'Victim was Stepparent'
  'SC' 'Victim was Stepchild'
  'SS' 'Victim was Stepsibling'
  'OF' 'Other Family Member'
  'VO' 'Victim was Offender'
  'AQ' 'Victim was Acquaintance'
  'FR' 'Victim was Friend'
  'NE' 'Victim was Neighbor'
  'BE' 'Victim was Babysitter'
  'BG' 'Victim was Boyfriend/Girlfriend'
  'CF' 'Victim was Child of Boyfriend/Girlfriend'
  'HR' 'Homosexual Relationship'
  'XS' 'Victim was Ex-Spouse'
  'EE' 'Victim was Employee'
  'ER' 'Victim was Employer'
  'OK' 'Victim was Otherwise Known'
  'RU' 'Relationship Unknown'
  'ST' 'Victim was Stranger'.
****************************************************************************
*Selecting Records for Analysis
****************************************************************************
*A filter is used to select only the victim segment records with a
*homicide offense.
****************************************************************************.  
USE ALL.
COMPUTE filter_$=(homicide gt 0).
VARIABLE LABEL filter_$ 'Homicide offense (FILTER)'.
VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
****************************************************************************
*Generating Lists and Tables
****************************************************************************
*After identifying the victim segment records with a homicide offense,
*frequencies are requested for the variables of type of victim (V_TYPE),
*offender number(s) to be related (OFNSEQ1) and relationship of victim(s)
*to offender(s) (OVR1).   The latter two variables -- offender number(s)
*to be related (OFNSEQ) and offender victim relationship (OVR) -- must have
*at least one entry and can have up to ten entries.  For this quality
*control example, only the first variable is checked for each (OFNSEQ1
*and OVR1). 
*****************************************************************************.
FREQUENCIES
  VARIABLES= v_type ofnseq1 ovr1
  /ORDER  ANALYSIS .
*****************************************************************************
*Three tables are requested: (1) the joint distribution of values for
*circumstances surrounding the homicide – first occurrence (VCIRCUM1) by
*type of homicide (HOMICIDE), (2) the joint distribution of circumstances
*surrounding the homicide – second occurrence (VCIRCUM2) by type of
*homicide (HOMICIDE), and (3) the joint distribution of the values for
*additional justifiable homicide circumstance (VJUSTHOM) by type of
*homicide (HOMICIDE).
*The first table will show for each category of homicide offense, the
*homicide circumstances in the first occurrence of the aggravated
*assault/homicide circumstances variable (VCIRCUM1).  All homicides –
*murder and nonnegligent manslaughter, negligent manslaughter, and
*justifiable homicide -- must have a valid value in VCIRCUM1.
*The second table will show for each category of homicide offense,
*the homicide circumstances in the second occurrence of the aggravated
*assault/homicide circumstances variable (VCIRCUM2).  Only homicides
*defined as murder and nonnegligent manslaughter are allowed to have a
*valid value in VCIRCUM2.
*The third table will show for each category of homicide offense, the
*additional justifiable homicide circumstance (VJUSTHOM).  Only the
*homicides classified as justifiable homicides can have a valid value
*for this variable (VJUSTHOM).
**************************************************************************.
CROSSTABS
  /TABLES=vcircum1 vcircum2 vjusthom  BY homicide
  /FORMAT= AVALUE TABLES
  /CELLS= COUNT .
**************************************************************************
*A temporary SELECT IF is used to identify the specific victim segment
*records coded as murder or negligent manslaughter or justifiable homicide
*that do not have a victim type of “individual” (V_TYPE = I) or have no
*offender sequence number (OFNSEQ1) or have no aggravated assault/
*homicide circumstances (VCIRCUM1). The LIST command will print the
*values for originating agency identifier (ORI), the incident number
*(INC_NUM), the type of homicide (HOMICIDE), the type of victim (V_TYPE),
*offender sequence number – first occurrence (OFNSEQ1), and aggravated
*assault/homicide circumstances – first occurrence (VCIRCUM1).  Miscoded
*records can then be researched and corrected.
**************************************************************************.
TEMPORARY.
SELECT IF ((homicide = 1 or homicide = 2 or homicide = 3 ) AND
     (v_type ne 'I' or sysmis(ofnseq1) or vcircum1 = '  ')).  
LIST ori inc_num homicide v_type ofnseq1 vcircum1 .
**************************************************************************
*Similarly, a temporary SELECT IF is used to identify the victim records
*coded as justifiable homicide but do not have an additional justifiable
*homicide circumstance (VJUSTHOM) defined.  The LIST command will print
*the values for originating agency identifier (ORI), the incident number
*(INC_NUM), the type of homicide (HOMICIDE), the type of victim (V_TYPE),
*offender sequence number – first occurrence (OFNSEQ1), and additional
*justifiable homicide circumstance (VJUSTHOM).  Miscoded records can then
*be researched and corrected.
**************************************************************************.
TEMPORARY.
SELECT IF ((homicide = 3) AND (vjusthom = '  ')). 
LIST ori inc_num homicide v_type ofnseq1 vjusthom.
**************************************************************************
*Then, a series of temporary SELECT IFs is used to identify the victim
*records that show a homicide but for which the victim circumstance is
*not within the range of valid values for that type of homicide.  The
*LIST command will print the originating agency identifier (ORI), the
*incident number (INC_NUM), the type of homicide (HOMICIDE), the
*aggravated assault/homicide circumstances (VCIRCUM1) and, for the
*justifiable homicide offenses, the further specification of the
*circumstances (VJUSTHOM).  Miscoded records can then be researched
*and corrected.
***************************************************************************.
TEMPORARY.
SELECT IF ((homicide = 1) AND (vcircum1 >= '11')).  
LIST ori inc_num homicide vcircum1.

TEMPORARY.
SELECT IF ((homicide = 2) AND (vcircum1 < '30')).
LIST ori inc_num homicide vcircum1.

TEMPORARY.
SELECT IF ((homicide = 3) AND
	(vcircum1 < '20' OR vcircum1 > '21')).
LIST ori inc_num homicide vcircum1.

TEMPORARY.
SELECT IF ((homicide = 3) AND (vjusthom > 'G')).
LIST ori inc_num homicide vjusthom.