*HOMICIDE OFFENSES: QUALITY CONTROL OF OFFENSE SEGMENT REQUIRED VARIABLES*.
***************************************************************************
*For incidents that involve the homicide offenses of murder and
*nonnegligent manslaughter, negligent homicide, or justifiable
*homicide, are the required offense segment data fields completed
*and are the values valid?
***********************************************************.
*For the above-mentioned offenses, the following data fields
*are required: UCR offense code, offense attempted or completed,
*and type of weapon/force involved.  The allowable values for
*these data fields are listed in the FBI's Data Collection
*Guidelines and are incorporated into this example.  This data
*check can be performed on data sets at the local or state level.
*The following example uses a single agency data set The results
*will show which offense segment records need to be researched
*and corrected before submission at the state or national level.
*The narrative below explains the SPSS code used to prepare the
*file and to produce the lists and tables needed for quality
*control purposes.  To illustrate how an agency can self-audit,
*one month's data from one of the NIBRS certified localities
*reporting to the FBI in 1999 was modified.
***********************************************************.
*Preparing the Offense Segment File
***********************************************************
*Defining Homicide Offenses and Selecting Records for Analysis
***********************************************************.
*The block of code directly below retrieves and reviews the
*offense segment records to identify those with a homicide offense.
*A FILTER selects only those offense segment records with any
*one of the three homicide offenses (murder and nonnegligent manslaughter
*or 09A, negligent homicide or 09B, or justifiable homicide or 09C). 
***********************************************************.
GET FILE= 'Directory:\Path\Offense Segment.sav'.
COMPUTE filter_$=(off_code = '09A' | off_code = '09B' | off_code = '09C').
VARIABLE LABEL filter_$ "off_code = '09A' | off_code = '09B' | off_code = '09C' (FILTER)".
VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
***********************************************************
*Defining Value Labels
***********************************************************.
*Valid data labels are assigned.
***********************************************************.
VALUE LABELS
  off_code 
    '09A' 'Nonnegligent Homicide' 
    '09B' 'Negligent Homicide' 
    '09C' 'Justifiable Homicide'/
  att_comp
    'A' 'Attempted'
    'C' 'Completed'/
  weapon1
    '11' 'Firearm'
    '12' 'Handgun'
    '13' 'Rifle'
    '14' 'Shotgun'
    '15' 'Other Firearm'
    '20' 'Knife/Cutting Instrument'
    '30' 'Blunt Object'
    '35' 'Motor Vehicle'
    '40' 'Personal Weapons'
    '50' 'Poison'
    '60' 'Explosives'
    '65' 'Fire/Incendiary Device'
    '70' 'Drugs/Narcotics/Sleeping Pills'
    '85' 'Asphyxiation'
    '90' 'Other'
    '95' 'Unknown'
    '99' 'None'.

***********************************************************
*Generating Lists and Tables
***********************************************************.
*For the selected records, a FREQUENCIES table is requested for the
*data elements UCR offense code, offense attempted or completed,
*and type of weapon/force involved.  The frequency distribution
*for UCR offense codes 09A, 09B, and 09C will provide the total
*number of records to be evaluated.  For these three homicide
*offenses, the data element offense attempted/completed must be
*coded as completed (C).   A frequency distribution on ATT_COMP
*will show the joint distribution for the selected homicide offense
*records and offense attempted/completed.  A visual scan of the table
*will show whether all relevant records were coded with the only
*valid code (C).  Up to three types of weapons/force involved can be
*recorded for each offense. For this example, only the first
*occurrence of this variable --WEAPON1 -- is checked for the presence
*of data.  If there is a valid value for the data element WEAPON1,
*then the requirement is met.  Finally, the temporary SELECT IF searches 
*for homicide offense records for which data are missing from the two
*conditionally required fields  -- ATT_COMP and WEAPON1.   LIST requests
*the display of the values for originating agency identifier, incident
*number, UCR offense code, offense attempted or completed, and type of
*weapon/force involved (first occurrence as shown in variable WEAPON1)
*so that any records missing a value in ATT_COMP and/or WEAPON1 are
*identified so that they can be researched and corrected.
***********************************************************.
FREQUENCIES
  VARIABLES=off_code att_comp weapon1. 
  TEMPORARY.
SELECT IF ((off_code = '09A' | off_code = '09B' | off_code = '09C') AND
     (att_comp = ' ' or weapon1 = '  ')).
LIST ori inc_num off_code att_comp weapon1.