*INCIDENT REPORTS AND REQUIRED DATA SEGMENTS*.
**********************************************
*Does each incident record have at least one offense
*segment, one victim segment, and one offender segment?
**********************************************.
*According to the FBI Data Collection Guidelines, each
*incident record must have at least one offense segment
*record, one victim segment record, and one offender
*segment record. This example shows the SPSS code for
*determining which of the incident records comprising
*a single agency's data set fail to meet these criteria.
*The FBI's data quality controls and testing ensure that
*data submissions meet these criteria before the FBI
*accepts a dataset.  So, to illustrate how an agency can
*self-test, one month's data from one of the NIBRS
*certified localities reporting to the FBI in 1999 was modified.
***********************************************.
*Preparing the Offense, Victim, and Offender Segments
***********************************************.
*Defining the Segments to Count
***********************************************.
*To perform this quality control check, the first step is
*to retrieve the file and create new variables for offense
*count, victim count, and offender count, each with an
*initial setting of 0. For each incident record flagged as
*an initial submission (action = I), the new variables are
*assigned a value of 1 for each occurrence of an offense
*segment record, victim segment record, or offender segment
*record. The segment record must be physically missing from
*the data set to remain set at 0.  An incident record is
*included only if it is flagged as an initial submission
*because only initial submissions are required to have at
*least one offense segment, one victim segment, and one
*offender segment.
*************************************************. 
GET FILE= ‘Directory:\Path\Agency Data.sav’.
COMPUTE ofns_cnt = 0.
COMPUTE vic_cnt = 0.
COMPUTE off_cnt = 0.
DO IF (action = 'I').
IF (ibr_rec = '2') ofns_cnt = 1.
IF (ibr_rec = '4') vic_cnt = 1.
IF (ibr_rec = '5') off_cnt = 1.
END IF.
**************************************************
*Sorting the File and Summing the Counts
**************************************************.
*Prior to executing the AGGREGATE command, which will sum
*the counts, the incident records are sorted on originating
*agency identifier, incident number, and IBR record segment
*number.  The AGGREGATE command requires that the file be
*presorted on the break variable.  In this example, it is
*sorted also on IBR record segment number to group the
*segments by segment number.
**************************************************.  
SORT CASES BY ori inc_num ibr_rec.
TEMPORARY.
SELECT IF (action = 'I').
AGGREGATE
  /OUTFILE= 'Directory:\Path\Example1.sav'
  /PRESORTED
  /BREAK=ori inc_num
  /off_cnt  'Count of offender records in incident' = sum(off_cnt)
  /vic_cnt 'Count of victim records in incident' = sum(vic_cnt)
  /ofns_cnt  'Count of offense records in incident' = sum(ofns_cnt).
***************************************************
*Generating the Tables and Lists
***************************************************.
*After the AGGREGATE command is run, frequency tables are
*produced to show the sums of the counts of the offense segments,
*victim segments, and offender segments for all incidents. The
*TEMPORARY / SELECT IF / LIST, which is run against the file
*created as a result of the AGGREGATE command, identifies the
*originating agency, incident number, offense count, victim count,
*and offender count for any incident that does not have at least
*one record in all of the required segments.
****************************************************.
GET FILE = 'Directory:\Path\Example1.sav'.
FREQUENCIES
  VARIABLES=ofns_cnt vic_cnt off_cnt.
TEMPORARY.
SELECT IF (ofns_cnt = 0 or vic_cnt = 0 or off_cnt = 0). 
LIST ori inc_num ofns_cnt vic_cnt off_cnt.