*********************************************************************************;
*                                                                               *;
* Program Name:  C:\JRSA\JUV_TIME.SAS                                           *;
*                                                                               *;
* SAS Download Code                                                             *;
*                                                                               *;
* Purpose:  Juvenile Multiple Offender Incident Research Question 3:            *;
*                                                                               *;
*   At what time of day are most juvenile multiple offender                     *;
*   property offenses committed?                                                *;
*                                                                               *;                              *;
*                                                                               *;
*********************************************************************************;
LIBNAME PERM 'C:\JRSA\DATA\';
OPTIONS LINESIZE=80 FIRSTOBS=1 OBS=MAX NOFMTERR;
%LET LINESZ = 120;

PROC FORMAT;
     INVALUE OFF
        '200' =  200  	 '13A' =  130  	 '13B' =  171  	 '13C' =  172  
        '510' =  510  	 '220' =  140  	 '250' =  250  	 '290' =  290  
        '35A' =  350  	 '35B' =  351  	 '270' =  270  	 '210' =  210  
        '26A' =  260  	 '26B' =  261  	 '26C' =  262  	 '26D' =  263  
        '26E' =  264  	 '39A' =  390  	 '39B' =  391  	 '39C' =  392  
        '39D' =  393  	 '09A' =  90  	 '09B' =  198  	 '09C' =  199  
        '100' =  190  	 '23A' =  160  	 '23B' =  161  	 '23C' =  162  
        '23D' =  163     '23E' =  164  	 '23F' =  165  	 '23G' =  166  
        '23H' =  167  	 '240' =  150  	 '370' =  370  	 '40A' =  400  
        '40B' =  401  	 '120' =  120  	 '11A' =  110  	 '11B' =  180  
        '11C' =  181  	 '11D' =  182  	 '36A' =  360  	 '36B' =  361  
        '280' =  280  	 '520' =  520    
              ;
     VALUE OFFENSE
       200 = 'Arson'
       130 = 'Aggravated Assault'	
       171 = 'Simple Assault'
       172 = 'Intimidation'	
       510 = 'Bribery'
       140 = 'Burglary/Breaking and Entering'
       250 = 'Counterfeiting/Forgery'
       290 = 'Destruction/Damage/Vandalism of Property'
       350 = 'Drug/Narcotics Violations'
       351 = 'Drug Equipment Violations'
       270 = 'Embezzlement'
       210 = 'Extortion/Blackmail'
       260 = 'False Pretenses/Swindle/Confidence Game'
       261 = 'Credit Card/Automated Teller Machine Fraud'
       262 = 'Impersonation'
       263 = 'Welfare Fraud'
       264 = 'Wire Fraud'
       390 = 'Betting/Wagering'
       391 = 'Operating/Promoting/Assisting Gambling'
       392 = 'Gambling Equipment Violations'
       393 = 'Sports Tampering'
        90 = 'Murder and Nonnegligent Manslaughter'
       198 = 'Negligent Manslaughter'
       199 = 'Justifiable Homicide'
       190 = 'Kidnaping/Abduction'
       160 = 'Pocket-picking'
       161 = 'Purse-snatching'
       162 = 'Shoplifting'
       163 = 'Theft From Building'
       164 = 'Theft From Coin-Operated Machine or Device'
       165 = 'Theft From Motor Vehicle'
       166 = 'Theft of Motor Vehicle Parts or Accessories'
       167 = 'All Other Larceny'
       150 = 'Motor Vehicle Theft'
       370 = 'Pornography/Obscene Material'
       400 = 'Prostitution'
       401 = 'Assisting or Promoting Prostitution'
       120 = 'Robbery'
       110 = 'Forcible Rape'
       180 = 'Forcible Sodomy'
       181 = 'Sexual Assault With An Object'
       182 = 'Forcible Fondling'
       183 = 'Rape of a Male'
       360 = 'Incest'
       361 = 'Statutory Rape'
       280 = 'Stolen Property Offenses'
       520 = 'Weapon Law Violations'
           ;
RUN;



DATA CRIMES;
     SET PERM.INCIDENT_LEVEL_FILE;

     LABEL INDEX    =  'Recoded Offenses'
           JUV_OFF  =  'Incident Involved Juvenile Offender'
           MSOFFGP  =  'Group Of Index'
           TYPE_INC =  'Offender Type';

    IF (OFF_CNT EQ 1) THEN TYPE_INC = 1;
      ELSE IF (OFF_CNT GT 1) THEN TYPE_INC = 2;
      ELSE TYPE_INC = 0;

    IF (MSVOFF = 90) THEN INDEX = 1;
      ELSE IF (MSVOFF = 110) THEN INDEX = 2;
      ELSE IF (MSVOFF = 120) THEN INDEX = 3;
      ELSE IF (MSVOFF = 130) THEN INDEX = 4;
      ELSE IF (MSVOFF = 140) THEN INDEX = 5;
      ELSE IF (160 LE MSVOFF LE 167) THEN INDEX = 6;
      ELSE IF (MSVOFF = 150) THEN INDEX = 7;
       ELSE INDEX = 8;

     IF (1 LE INDEX LE 4) THEN MSOFFGP = 1;
       ELSE IF (5 LE INDEX LE 7) THEN MSOFFGP = 2;
       ELSE IF (INDEX = 8) THEN MSOFFGP = 3;

     IF (OFFADULT GE 1) AND (OFF1017 EQ 0) THEN JUV_OFF = 0;
     IF (OFF1017 GE 1) THEN JUV_OFF = 1;
RUN;


PROC FORMAT;
     VALUE TYPE_INC
       0 = 'Missing'
       1 = 'Single Offender'
       2 = 'Multiple Offenders'
         ;
     VALUE INDEX
       1 = 'Murder and Nonnegligent Manslaughter'
       2 = 'Forcible Rape'
       3 = 'Robbery'
       4 = 'Aggravated Assault'
       5 = 'Burglary'
       6 = 'Larceny'
       7 = 'Motor Vehicle Theft'
       8 = 'All other offenses'
         ;
     VALUE MSOFFGP
       1 = 'Person Offenses'
       2 = 'Property Offenses'
       3 = 'Other offenses'
         ;
     VALUE JUV_OFF
       1 = 'Juvenile offender(s)'
       0 = 'Adult offender(s)'
         ;
RUN;


PROC SORT DATA=CRIMES ;
     BY TYPE_INC;
RUN;


GOPTIONS RESET=GLOBAL GUNIT=PCT DEVICE=WIN NOBORDER
         FTEXT=ZAPF HTITLE=5 HTEXT=2.5 HBY=4 FBY=ZAPF ROTATE=LANDSCAPE;

TITLE1 H=3 F=ZAPF C=BLACK 'Graph 1:  Peak Time of Day for Juvenile Multiple Offender Property Offense Incidents';
TITLE2 H=3 F=ZAPF C=BLACK 'Property Offense Incidents';

FOOTNOTE1;

SYMBOL1 COLOR=BLACK
        INTERPOL=JOIN
        VALUE=NONE
        LINE=1;

AXIS1  ORDER=(1 TO 23 BY 2)
       WIDTH=1
       MINOR=NONE
       VALUE=(COLOR=BLACK HEIGHT=2)
       LABEL=(COLOR=BLACK HEIGHT=2)
       OFFSET=(0, 0);

AXIS2  ORDER=(0 to 10 by 2 )
       MINOR=NONE
       LABEL=(F=ZAPF HEIGHT=2 A=90 'Percent');


PROC FREQ DATA=CRIMES NOPRINT;
     TABLES INC_HR
           /OUT=GRAPH;
RUN;


PROC GPLOT DATA=GRAPH;
     PLOT PERCENT*INC_HR /
          HAXIS=AXIS1
          VAXIS=AXIS2
          GRID;
    LABEL PERCENT = 'Percent'
          INC_HR  = 'Reported Time of Incident';
RUN;
QUIT;