*INTIMATE PARTNER MULTIPLE SEGMENT ANALYSIS
*SPSS DOWNLOAD CODE
*****************************************************************************
*Research Question 2: Is there a difference in weapon use against female vs.
*male victims of intimate partner violence?
*****************************************************************************.
*The assumptions for the following example are:
*1. The original data file was created as described in “Reading A Multi-Level
*Data File Into SPSS”;
*2. An aggregated flat file was created as described in “Creating An Incident-
*Level Aggregated Flat File”;
*3. The individual data segments were saved in separate files as described in
*“Preparing Individual File Segments For Detailed Analysis”;
*4. The victim data segment was retrieved, new variables created, and a new file
*named and saved as shown in “Intimate Partner Single Segment Analysis – 
*Research Question 1”;
*5. The file saved in “Intimate Partner Single Segment Analysis – Research
*Question 1” was matched with the offense segment file and new variables
*created; and
*6. The matched file saved in “Intimate Partner Multiple Segment Analysis –
*Research Question 1” was retrieved and new variables created.
******************************************************************************.
*Defining the Variables
*This example will use the matched file saved in the “Intimate Partner Multiple
*Segment Analysis – Research Question 1” because the created variables of
*intimate partner relationship and intimate partner most serious violent offense
*and the existing gender and weapon use variables are needed to answer this
*question.  
******************************************************************************.
GET FILE = 'Directory:\Path\Intimate partner_vicoffense.sav'.
******************************************************************************.
*A new variable MSWPN is created to represent the most serious weapon used in
*the incident.  Each NIBRS record can have up to three weapons recorded.
*First, VALUE LABELS are assigned to the three weapon variables (WEAPON1,
*WEAPON2, and WEAPON3).  Second, the values of the three weapon variables
*are grouped into six categories by a RECODE as follows: 
*FIREARM (1) includes firearm, handgun, rifle, shotgun, and other firearm;
*OBJECT (2) includes knife or cutting instrument, blunt object,and motor vehicle;
*PERSONAL WEAPONS remains as personal weapons(3);
*OTHER WEAPON (4) includes poison, explosives, fire or incendiary device,
*drugs or narcotics or sleeping pills, asphyxiation, and other;
*NONE remains as none (5); and
*UNKNOWN or missing or not applicable(9)includes unknown and default.
*Third, the new variable MSWPN is computed where the value of 1 represents
*the most serious weapon category.  Fourth, the VALUE LABELS are assigned for
*MSWPN variable and, finally, the value 9 is defined as the MISSING VALUE.
******************************************************************************.
VALUE LABELS weapon1 to weapon3
  '11' 'Firearm'
  '12' 'Handgun'
  '13' 'Rifle'
  '14' 'Shotgun'
  '15' 'Other Firearm'
  '20' 'Knife/Cutting Instrument'
  '30' 'Blunt Object'
  '35' 'Motor Vehicle'
  '40' 'Personal Weapons'
  '50' 'Poison'
  '60' 'Explosives'
  '65' 'Fire/lncendiary Device'
  '70' 'Drugs/Narcotics/Sleeping Pills'
  '85' 'Asphyxiation'
  '90' 'Other'
  '95' 'Unknown'
  '99' 'None'
  '00' 'Default'.
RECODE weapon1 to weapon3 
   ('11','12','13','14','15' = 1)
   ('20','30','35' = 2)
   ('40' = 3)
   ('50','60','65','70','85','90' = 4)
   ('99' = 5)
   ('95','00' = 9)into wpn1 to wpn3.
COMPUTE mswpn = min.1(wpn1 to wpn3).
VARIABLE LABELS mswpn 'Most Serious Weapon'.
VALUE LABELS mswpn 1 'Firearm'
   2 'Object'
   3 'Personal Weapon'
   4 'Other Weapon'
   5 'None'
   9 'Unknown/missing/not applicable'.
MISSING VALUES mswpn (9).
******************************************************************************.
*Producing the Output
*The CROSSTABS command generates a table for all victims of an intimate   
*partner offender-victim relationship that shows the count and percent within
*female and male victim gender groups for each category of most serious weapon
*reportedly used against the victim.
******************************************************************************.
CROSSTABS
  /TABLES=mswpn  BY v_gender
  /FORMAT= AVALUE TABLES
  /CELLS= COUNT COLUMN.