*INTIMATE PARTNER MULTIPLE SEGMENT ANALYSIS
*SPSS DOWNLOAD CODE
*****************************************************************************
*Research Question 1: What violent offenses did intimate partners commit and
*where were the offenses committed?
*****************************************************************************.
*The following code creates the variables and matches the segments necessary
*to answer the research question.  When using this code, insert the paths and
*file names of the data files to be used for the analysis.  As noted below,
*this example relies upon a saved file that was created in the Intimate
*Partner Single Segment Analysis – Research Question 1 that is matched to the
*offense segment data file.  Also, remember to give names to the two files that
*are to be saved.  If you need any assistance working with the syntax provided,
*please contact us.
******************************************************************************.
*The assumptions for the following example are:
*1.The original data file was created as described in “Reading A Multi-Level
*Data File Into SPSS”;
*2.An aggregated flat file was created as described in “Creating An
*Incident-Level Aggregated Flat File”;
*3.The individual data segments were saved in separate files as described in
*“Preparing Individual File Segments For Detailed Analysis”;
*4.The victim data segment was retrieved, new variables created, and a new
*file named and saved as shown in “Intimate Partner Single Segment Analysis
*– Research Question 1”.
******************************************************************************.
*Defining the Variables
*This example will merge the victim segment modified in the “Intimate Partner
*Single Segment Analysis – Research Question 1” example with the offense segment
*file saved in “Preparing Individual File Segments For Detailed Analysis”.  The
*intimate partner single segment file is needed because the created variable
*OVRRCD is necessary in answering this research question.  From the offense
*segment file, the incident location will be obtained.  Both files must be
*sorted on the same variables first. The offense segment file is sorted on the
*variables originating agency identifier (ORI), incident number (INC_NUM),and
*offense (OFFENSE).  The offense segment is then re-saved under the same name.
*The intimate partner file is retrieved and sorted on originating agency
*identifier (ORI), incident number (INC_NUM), and most serious victim offense (MSVOFF).
********************************************************************************.
GET FILE = 'Directory:\Path\offense segment.sav'.
SORT CASES BY ori inc_num offense.
SAVE outfile = 'Directory:\Path\offense segment.sav'.
GET FILE = 'Directory:\Path\Intimate partner_vic.sav'.
SORT CASES BY ori inc_num msvoff.
********************************************************************************.
*To merge the two files, the sorted intimate partner victim segment file is matched
*against the sorted offense segment file.  The offense variable (OFFENSE) from the
*offense segment file is RENAMEd most serious victim offense (MSVOFF) because it is
*one of the sort variables and the file is re-sorted on originating agency identifier 
*(ORI), incident number (INC_NUM), and most serious victim offense (MSVOFF).  The 
*EXECUTE command matches the files.
*********************************************************************************.
MATCH FILES /FILE=*
 /TABLE='Directory:\Path\offense segment.sav'.
 /RENAME offense=msvoff
 /BY ori inc_num msvoff.
EXECUTE.
*********************************************************************************.
*Using the resulting active file, a new intimate partner violent offense variable
*(IPVOFF1 through IPVOFF10) is created from each existing victim offense variable
*(VOFF1 through VOFF10). The violent offenses are RECODEd into the following
*categories:  (1) murder, manslaughter, justifiable homicide; (2) rape and sexual
*assault offenses; (3) all other assaults and kidnaping/abduction; (4) robbery.
*Non-violent offenses are grouped (9) and will be excluded from this analysis.
*This RECODE also reorders offense seriousness. The reordering is necessary 
*because according to the FBI's hierarchical offense structure, certain property 
*offenses are classified as more serious than some violent offenses
*such as simple assault and intimidation.
***********************************************************************************.
DO REPEAT voff = voff1 to voff10
  /ipvoff = ipvoff1 to ipvoff10. 
RECODE voff (90,198,199 = 1)
  (110,180,183,181,182 = 2)
  (120 = 3)
  (130,171,172,190 = 4)
  (else = 9)into ipvoff.
END REPEAT.
**********************************************************************************.
*Next, a COMPUTE creates a new intimate partner most serious violent offense variable
*(IPMSVOFF).  This ensures that each victim is counted only once in the analysis.
*IPMSVOFF is COMPUTEd from the new variable IPVOFF.  Each intimate partner victim
*offense (IPVOFF1 through IPVOFF10) is evaluated and the most serious offense is
*selected based upon the reordering accomplished in the above RECODE.  Rape and sexual
*assault offenses include: forcible rape, forcible sodomy, rape of a male, sexual
*assault with an object, and forcible fondling.  All assaults, kidnaping/abduction
*includes: aggravated assault, simple assault, intimidation, and kidnaping/abduction.
*The VARIABLE LABEL is assigned to IPMSVOFF (intimate partner most serious violent 
*offense) and the VALUE LABELS are assigned for the offense categories.  The other, 
*non-violent offense category is defined as MISSING.
**************************************************************************************.
COMPUTE ipmsvoff = min.1(ipvoff1 to ipvoff10).
VARIABLE LABELS ipmsvoff 'Intimate partner most serious violent offense'.
value labels ipmsvoff ipvoff1 to ipvoff10 
 1 'Murder, manslaughter, justifiable homicide'
 2 'Rape and sexual assault offenses'
 3 'Robbery'
 4 'All assaults, kidnaping/abduction'
 9 'Other non-violent offense'.
MISSING VALUES ipmsvoff (9).
***************************************************************************************.
*IP_OVR is created to further define the intimate partner offender-victim relationships.
*The file saved in the Intimate Partner Single Segment Analysis -Research Question 1
*contains the variable OVRRCD that was created to identify intimate partner relationships
*as a relationship category.  OVRRCD distinguished intimate partner relationships from
*other categories of relationships and it is relied upon here to create the new variable
*IP_OVR.  IP_OVR allows a separate examination of the various intimate partner 
*relationships: boyfriend/girlfriend, common-law spouse, homosexual relationship, 
*spouse, and ex-spouse.
*
*The victim segment allows the reporting of up to 10 offender-victim relationships
*(OVR1 through OVR10).  In incidents with multiple offenders, the relationship(s) of an
*intimate partner type will not always be reported in the first OVR1 variable.  The 
*syntax searches through the 10 relationship variables (OVRRCD1 through OVRRCD10) 
*to identify the intimate partner relationship(s).  The original OVR value of 
*that relationship is stored in the new variable IP_OVR.
*
*To create IP_OVR, it is defined as a STRING alpha variable that is 2 characters 
*in length (a2).  It is initialized as two blanks by the COMPUTE.  Each OVRRCD 
*variable (OVRRCD1 through OVRRCD10)is evaluated in conjunction with the new 
*variable IP_OVR to assign a specific intimate partner relationship value to 
*IP_OVR.  This assigned value is equal to the pre-existing two character
*alpha value of OVR or offender-victim relationship.  OVR is the variable 
*on the victim segment file that was used to create the relationship grouping 
*variable OVRRCD.  The values of OVR are specific relationship codes.  So, if OVRRCD 
*is equal to 1, which indicates an intimate partner relationship, then the original
*OVR value is needed for this analysis.
*
*The VARIABLE LABEL is then assigned to the new variable IP_OVR and the variable's 
*VALUE LABELS are assigned.
***************************************************************************************.
STRING ip_ovr (a2).
COMPUTE ip_ovr = '  '.
IF (ovrrcd1 = 1)ip_ovr = ovr1.
IF (ip_ovr = '  ' and ovrrcd2 = 1)ip_ovr = ovr2.
IF (ip_ovr = '  ' and ovrrcd3 = 1)ip_ovr = ovr3.
IF (ip_ovr = '  ' and ovrrcd4 = 1)ip_ovr = ovr4.
IF (ip_ovr = '  ' and ovrrcd5 = 1)ip_ovr = ovr5.
IF (ip_ovr = '  ' and ovrrcd6 = 1)ip_ovr = ovr6.
IF (ip_ovr = '  ' and ovrrcd7 = 1)ip_ovr = ovr7.
IF (ip_ovr = '  ' and ovrrcd8 = 1)ip_ovr = ovr8.
IF (ip_ovr = '  ' and ovrrcd9 = 1)ip_ovr = ovr9.
IF (ip_ovr = '  ' and ovrrcd10 = 1)ip_ovr = ovr10.
VARIABLE LABELS ip_ovr 'Offender victim relationship for intimate partners'.
VALUE LABELS ip_ovr
  'BG' 'Boyfriend/girlfriend'
  'CS' 'Common-law spouse'
  'HR' 'Homosexual relationship'
  'SE' 'Spouse'
  'XS' 'Ex-spouse'.
****************************************************************************************.
*The first RECODE below converts the alphanumeric offense location variable (OFF_LOC) 
*into a numeric incident location variable (INC_LOC).  This recoding simplifies the 
*grouping of location types.  The incident location variable (INC_LOC) is RECODEd into 
*four categories: residential (1), non-residential (2), outdoors (3), and other/unknown(4). 
*Non-residential includes all public or private facilities other than residences. Outdoors 
*includes field/woods, highway/road/alley, lake/waterway, and construction site.  This 
*creates the grouped incident location variable called LOC_GRP.  The VARIABLE LABEL is 
*then assigned to the new variable IP_OVR and the variable's VALUE LABELS are assigned.
***************************************************************************************.
RECODE off_loc (convert) into inc_loc.
RECODE inc_loc (20 = 1)
  (6,10,13,16,= 3)
  (25,sysmis = 4)
  (else = 2)into loc_grp.  
VARIABLE LABELS loc_grp 'Incident location groups'.
VALUE LABELS loc_grp 
  1 'Residence/home'
  2 'Non-residential'
  3 'Outdoors'
  4 'Other/unknown/missing'.
*****************************************************************************************.
*Producing the Output
*The table generated shows for all victims of an intimate partner offender-victim 
*relationship the percentage of the most serious violent offense reported at each 
*incident location group.
*****************************************************************************************.
* General Tables.
TEMPORARY.
  VARIABLE LABELS ip_ovr '' ipmsvoff '' loc_grp '' .
SAVE OUTFILE = 'Directory:\Path\Intimate partner_vicoffense.sav'.
TABLES
  /FORMAT BLANK MISSING('.')
  /GBASE=CASES
  /TABLE=ip_ovr > (STATISTICS) > ipmsvoff > (STATISTICS)   BY loc_grp
  /STATISTICS
  count( loc_grp( F5.0 ) '')
  cpct( loc_grp( PCT5.1 ) '':ip_ovr ipmsvoff ) /TITLE  'Intimate Partner'+
 ' Relationships Most Serious Violent Offense by Location of Incident'.