*INTIMATE PARTNER SINGLE SEGMENT ANALYSIS
*SPSS DOWNLOAD CODE
**************************************************************************
*Research Question 1:  Is there a difference between gender and age groups
*in the types of injuries sustained by victims in violent intimate partner
*incidents?
**************************************************************************.
*The following code uses the victim segment to identify the incidents involving
*offender-victim intimate partner relationships and creates the variables
*needed to answer the research question.  When using this code, insert the
*paths and file names for the data files to be used.  Names must be given
*to the two files that are saved.  If you need any assistance working with
*this syntax, please contact us.
***************************************************************************.
*The assumptions for this example are:
*1. The data file was read as described in “Reading A Multi-Level Data File Into SPSS”;
*2. An aggregated flat file was created as described in “Creating An Incident-Level
*Aggregated Flat File In SPSS”; and
*3. The individual data segments were saved in separate files as described in
*“Creating An Incident-Level Aggregated Flat File In SPSS”.
***************************************************************************.
*Defining the Variables
*This research question requires the use of the victim segment only. After
*retrieving the victim segment file, the first step is to identify the incidents
*in which the offender-victim relationship is an intimate partner relationship.
*The FBI requires the coding of the offender-victim relationship for a Crime
*Against Person or a Robbery.  Since there can be up to 10 offenders identified,
*there can be up to 10 relationships coded.
*For each of the ten offender-victim relationship variables on each victim
*segment record, the alpha values of this variable are grouped by type of
*relationship.  The groups are RECODEd with numeric values for a new variable
*called OVRRCD. The intimate partner relationships of spouse, common-law spouse,
*boyfriend/girlfriend, ex-spouse, and homosexual relationship are assigned a value
*of 1.  Relationships within the family but not intimate partner are assigned a
*value of 2; outside the family but known to the victim are assigned a value of 3;
*stranger is assigned a value of 4; victim was offender is assigned a value of 5;
*relationship not known is assigned a value of 6; and if no value is coded a value
*of -1 is assigned.
******************************************************************************.
GET FILE = 'Directory:\Path\Victim segment.sav'.
DO REPEAT ovr = ovr1 to ovr10/
   ovrrcd = ovrrcd1 to ovrrcd10.
RECODE
  ovr ('SE','CS','BG','XS','HR' = 1)
      ('PA','SB','CH','GP',
       'GC','IL','SP','SC','SS','OF' = 2)
      ('AQ','FR','NE','BE','CF','EE','ER','OK' = 3)
      ('RU' = 6)
      ('ST' = 4) 
      ('VO' = 5)('  ' = -1)INTO ovrrcd.
********************************************************************************.
*The IF statement creates the new variable called INTMPART to identify the
*intimate partner relationships or those for which the new variable OVRRCD has
*a value of 1. 
********************************************************************************.
IF (ovrrcd = 1)intmpart = 1.
END REPEAT.
********************************************************************************.
*As noted above, certain victim offenses are not required to have an offender-victim
*relationship.  The FBI guidelines require offender-victim relationship to be
*reported for 14 offenses.  The following DO IF / RECODE uses the most serious
*victim offense variable (MSVOFF) to evaluate each newly defined variable OVRRCD
*(1 through 10). A  value of 9 is assigned to represent “not applicable” to
*distinguish cases for which an offender-victim relationship is not required from
*those that should have been coded but are simply missing (-1).  So, if the most
*serious victim offense was not a Crime Against Person or a Robbery, then the
*offender-victim relationship value is 9 or “not applicable”.  MISSING VALUES
*are then defined as both -1 and 9.  VALUE LABELS are assigned to OVRRCD1 through
*OVRRCD10, and variable labels are assigned to the new variable INTMPART.
*(The most serious victim offense variable was defined and saved in the victim
*segment in “Creating An Incident-Level Aggregated Flat File In SPSS”.)
*********************************************************************************.
DO IF ((msvoff gt 130 and msvoff lt 171) or msvoff gt 199).
RECODE ovrrcd1 to ovrrcd10 (-1 = 9).
END IF.
MISSING VALUES ovrrcd1 to ovrrcd10 (-1,9).
VALUE LABELS ovrrcd1 to ovrrcd10
    1 'Intimate Partner'
    2 'Other Family Member'
    3 'Other Known'
    4 'Stranger' 
    5 'Victim is Offender'
    6 'Relationship Unknown'
   -1 'Missing Relationship Information'
    9 'Not Applicable'.
VARIABLE LABELS intmpart 'Intimate Partner Relationship'.
*********************************************************************************.
*The TEMPORARY / SELECT IF selects the cases where any of the offender-victim
*relationships (OVRRCD1 through OVRRCD10) was an intimate partner relationship.
*The SAVE command saves the data in a new file.
*********************************************************************************.
TEMPORARY.
SELECT IF (intmpart = 1).
SAVE OUTFILE = 'Directory:\Path\Intimate partner1 file.sav'.
*********************************************************************************.
*This block of code creates a numeric victim gender variable V_GENDER and a victim
*age group variable AGEGRP.   The MISSING VALUES, VALUE LABELS, and VARIABLE LABELS
*are assigned for these new variables.
**********************************************************************************.
GET FILE = 'Directory:\Path\Intimate partner1 file.sav'.
RECODE vic_sex ('M' = 2)('F' = 1)(else = 0)into v_gender.
VALUE LABELS v_gender 1 'Female' 2 'Male' 0 'Unknown/missing'.
MISSING VALUES v_gender (0).
VARIABLE LABELS v_gender 'Victim Gender'.
RECODE v_age (.1 thru 17 = 1)
           (18 thru 24 = 2)
            (25 thru 34 = 3)
            (35 thru 44 = 4)	
            (45 thru 54 = 5)
            (55 thru 64 = 6)
            (65 thru 95 = 7)into agegrp.	
VALUE LABELS agegrp
    1 'Under age 18'
    2 '18 thru 24'
    3 '25 thru 34'
    4 '35 thru 44'	 
    5 '45 thru 54'
    6 '55 thru 64'
    7 'Age 65 or older'.
VARIABLE LABELS agegrp 'Victim Age Group'.
**********************************************************************************.
*This DO REPEAT / RECODE creates a set of victim injury variables INJ1RCD to INJ5RCD
*whereby the original alpha values of the V_INJ1 to V_INJ5 variables are reclassified
*into numeric values.  This RECODE creates three categories of injury: physical injury,
*apparent minor injury, and no injury. For example, a victim case with V_INJ1 = U
*(unconscious) and V_INJ2 = T (loss of teeth) will be recoded as INJ1RCD = 2 and
*INJ2RCD = 2.   A blank is defined as system missing.
***********************************************************************************.
DO REPEAT vic_inj = v_inj1 to v_inj5/
   rcd = inj1rcd inj2rcd inj3rcd inj4rcd inj5rcd.
RECODE vic_inj ('B','I','L','O','T','U' = 2)
  ('M'=3)('N'=4)(' '=sysmis)('9'=9)into rcd.
END REPEAT.
***********************************************************************************.
*The DO IF / RECODE evaluates the most serious victim offenses (MSVOFF) for which a
*victim injury is required to be coded and assigns a value of 9 or “not applicable”
*to the new victim injury variables (INJ1RCD through INJ5RCD) if victim injury
*reporting was not required.  The FBI guidelines require victim injury reporting
*for 9 offenses, including extortion/blackmail.
***********************************************************************************.
DO IF ((msvoff gt 130 and msvoff lt 171) or msvoff gt 199 or msvoff = 210). 
RECODE inj1rcd to inj5rcd (sysmis,9 = 9).
END IF.
VALUE LABELS inj1rcd to inj5rcd 
  2 'Physical injury'
  3 'Apparent minor injury'
  4 'No injury'
  9 'Not applicable'.
MISSING VALUES inj1rcd to inj5rcd (9).
***********************************************************************************.
*To count each unique victim record only once in this analysis, the most serious
*victim injury variable (MSVINJ) is created with the COMPUTE and MSVINJ is assigned
*a value of 1 to 4, where 1 represents the most serious level of injury.
*To include death as an injury, the cases where the most serious offense MSVOFF
*is reported as murder or nonnegligent manslaughter (90) or negligent homicide (198)
*or justifiable homicide (199) are identified by the IF statement and the value of 1
*is assigned to variable MSVINJ or most serious victim injury.  The FBI guidelines
*do not require victim injury reporting for murder and nonnegligent manslaughter,
*negligent homicide, justifiable homicide, incest, or forcible fondling.)
*VALUE LABELS are assigned for MSVINJ and the VARIABLE LABEL for MSVINJ is defined.
************************************************************************************.
COMPUTE msvinj = min.1(inj1rcd to inj5rcd).
IF (msvoff = 90 OR msvoff = 198 or msvoff = 199)msvinj = 1.
VALUE LABELS msvinj 1 'Death'
  2 'Serious physical injury'
  3 'Apparent minor injury'
  4 'No injury'
  9 'Not applicable'.
VARIABLE LABELS msvinj 'Most serious victim injury'.
***********************************************************************************.
*Producing the Output
*To answer the research question, a cross-tabulation table showing the victim age
*group (AGEGRP) by most serious victim injury (MSVINJ) by victim gender (V_GENDER)
*is generated. Values are presented in ascending order with row percentages.  The
*file is saved with a new name and will be used in Intimate Partner Multiple
*Segment Analysis - Research Question 1.
***********************************************************************************.
CROSSTABS
  /TABLES=agegrp  BY msvinj BY v_gender
  /FORMAT= AVALUE TABLES
  /CELLS= row .
SAVE OUTFILE = 'Directory:\Path\Intimate partner_vic.sav'.